macro packandgo (composition à emporter)

sev-et-fab · Avril 24, 2019, 9:15

d.roger · Avril 24, 2019, 10:06

Bonjour,

Pour moi elle fonctionne très bien, sous réserve de modifier le chemin du fichier à ouvrir ("C:\Program Files\SOLIDWORKS Corp\SOLIDWORKS\samples\tutorial\advdrawings\handle.sldasm") qui n'existe pas sur mon PC et de le remplacer par un chemin valide.

Cordialement,

sev-et-fab · Avril 24, 2019, 10:07

oui j'ai bien changé le chemin

mais cela me donne une erreur "erreur d'execution '91': Variable objet ou varable de bloc With non définie" lorsque que je fais débogage cela but sur "Set swModelDocExt = swModelDoc.Extension" au début du programme

Par contre j'ai copié le code dans un fichier .SWP et je l'execute la macro depuis solidworks, je ne vois pas pourquoi cela ne fonctionne pas.

sev-et-fab · Avril 24, 2019, 11:12

est-ce que je n'aurais pas une reference de bibilotheque manquantes?

remrem · Avril 24, 2019, 11:20

Salut,

Non. Si tu avais une références manquantes, tu aurais un autre type d'erreur.

Je pense que tu as une erreur de chemin, de droit ou de lecture seule. Et ton objet swModelDoc doit rester vide. Essaye de faire un pas à pas avec [F5] pour vérifier la valeur de ton objet.

d.roger · Avril 24, 2019, 11:30

C'est exactement ce que j'ai fait et j'ai les mêmes références que toi (à la version de SW prêt).

Es-tu sur que les chemins et noms d'assemblage que tu as mis sont valides ?

Pour voir si cela vient de là, remplace les lignes :

openFile = "C:\Program Files\SOLIDWORKS Corp\SOLIDWORKS\samples\tutorial\advdrawings\handle.sldasm"
Set swModelDoc = swApp.OpenDoc6(openFile, swDocASSEMBLY, swOpenDocOptions_Silent, "", errors, warnings)

par :

Set swModelDoc = swApp.ActiveDoc

puis ouvre un assemblage avant de lancer la macro.

d.roger · Avril 24, 2019, 11:38

Petite question aussi, c'est bien un assemblage que tu as mis comme fichier dans le chemin ?

d.roger · Avril 24, 2019, 11:46

Encore une petite question, tu as bien mis l'extension de ton assemblage dans le nom du fichier même si celle-ci n'est pas affichée dans l'explorateur Windows (.sldasm) ?

sev-et-fab · Avril 24, 2019, 11:38

cela fonctionne j'avais du faire une erreur dans la copie du chemin .

Je voudrais rajouter une fonction au "PackAndGo" renommer toutes les fichiers qui contient "XXXXX" et les renommer avec un numero 44444 (precision le XXXXX n'est pas en suffixe ou en prefixe)

sev-et-fab · Avril 24, 2019, 1:37

oui c'est bien un assemblage dans le fichier du chemin avec le nom de l'extention

remrem · Avril 24, 2019, 1:42

Essaye un truc comme cela :

' Verify document paths and filenames after adding prefix and suffix
ReDim pgGetFileNames(namesCount - 1)
ReDim pgDocumentStatus(namesCount - 1)
status = swPackAndGo.GetDocumentSaveToNames(pgGetFileNames, pgDocumentStatus)
For i = 0 To (namesCount - 1)
     If Instr(pgGetFileNames(i), "XXXXXX") <> 0 Then
          pgGetFileNames(i) = Replace(pgGetFileNames(i), "XXXXX", "444444")
     End If
Next i

sev-et-fab · Avril 24, 2019, 2:16

Cela ne fonctionne pas?

il faut que je le place ou dans le code? je l'ai mis a la fin comme ceux-ci

'[.....]

' Add a prefix and suffix to the new Pack and Go filenames-------------------- (Aplatissez la structure de dossiers Pack and Go; enregistrer tous les fichiers dans le répertoire racine)
swPackAndGo.AddPrefix = "SW_"
swPackAndGo.AddSuffix = "_PackAndGo"


' Verify document paths and filenames after adding prefix and suffix----------------- (Aplatissez la structure de dossiers Pack and Go; enregistrer tous les fichiers dans le répertoire racine)
ReDim pgGetFileNames(namesCount - 1)
ReDim pgDocumentStatus(namesCount - 1)
status = swPackAndGo.GetDocumentSaveToNames(pgGetFileNames, pgDocumentStatus)
For i = 0 To (namesCount - 1)
If InStr(pgGetFileNames(i), "xxxxx") <> 0 Then
pgGetFileNames(i) = Replace(pgGetFileNames(i), "xxxxx", "yyyyy")
End If
Next i



 ' Verify document paths and filenames after adding prefix and suffix------------------ (Vérifier les chemins d'accès aux documents et les noms de fichiers après avoir ajouté un préfixe et un suffixe)
ReDim pgGetFileNames(namesCount - 1)
ReDim pgDocumentStatus(namesCount - 1)
status = swPackAndGo.GetDocumentSaveToNames(pgGetFileNames, pgDocumentStatus)
Debug.Print ""
Debug.Print "  My Pack and Go path and filenames after adding prefix and suffix: "
For i = 0 To (namesCount - 1)
     Debug.Print "    My path and filename is: " & pgGetFileNames(i)
Next i
' Pack and Go
statuses = swModelDocExt.SavePackAndGo(swPackAndGo)

End Sub

remrem · Avril 24, 2019, 2:45

Il ne suffit pas de coller des bouts de code à la suite des autres. Il faut essayer de comprendre un peu...

swPackAndGo.AddPrefix = "SW_"
swPackAndGo.AddSuffix = "_PackAndGo"

Ajoute un préfixe et un suffixe. Vu que tu n'as pas changé les valeurs je doute que tu en ais besoin. Tu peux le supprimer.

ReDim pgGetFileNames(namesCount - 1)
ReDim pgDocumentStatus(namesCount - 1)
status = swPackAndGo.GetDocumentSaveToNames(pgGetFileNames, pgDocumentStatus)
Debug.Print ""
Debug.Print "  My Pack and Go path and filenames after adding prefix and suffix: "
For i = 0 To (namesCount - 1)
     Debug.Print "    My path and filename is: " & pgGetFileNames(i)
Next i

Cela ne fait qu'afficher les noms finaux des documents dans le débugeur. Je pense que tu n'en a pas besoin.

Fait un test en pas à pas pour voir si les noms des fichiers évoluent correctement.

d.roger · Avril 24, 2019, 3:09

Voici un bout de macro fonctionnelle et épurée des affichages dans le débogueur :

Option Explicit

Dim swApp As SldWorks.SldWorks
Dim swModelDoc As SldWorks.ModelDoc2
Dim swModelDocExt As SldWorks.ModelDocExtension
Dim swPackAndGo As SldWorks.PackAndGo
Dim openFile As String
Dim pgFileNames As Variant
Dim pgFileStatus As Variant
Dim pgGetFileNames As Variant
Dim pgDocumentStatus As Variant
Dim status As Boolean
Dim warnings As Long
Dim errors As Long
Dim i As Long
Dim namesCount As Long
Dim myPath As String
Dim statuses As Variant

Sub main()

    Set swApp = Application.SldWorks

    ' Open assembly
    openFile = "C:\Users\DRO\Desktop\Nouveau dossier\Assemblage1.SLDASM"
    Set swModelDoc = swApp.OpenDoc6(openFile, swDocASSEMBLY, swOpenDocOptions_Silent, "", errors, warnings)
    'Set swModelDoc = swApp.ActiveDoc
    Set swModelDocExt = swModelDoc.Extension

    ' Get Pack and Go object
    Set swPackAndGo = swModelDocExt.GetPackAndGo

    ' Get number of documents in assembly
    namesCount = swPackAndGo.GetDocumentNamesCount

    ' Include any drawings, SOLIDWORKS Simulation results, and SOLIDWORKS Toolbox components
    swPackAndGo.IncludeDrawings = True
    swPackAndGo.IncludeSimulationResults = True
    swPackAndGo.IncludeToolboxComponents = True

    ' Get current paths and filenames of the assembly's documents
    'status = swPackAndGo.GetDocumentNames(pgFileNames)

    ' Get current save-to paths and filenames of the assembly's documents
    status = swPackAndGo.GetDocumentSaveToNames(pgFileNames, pgFileStatus)

    ' Set document paths and names for Pack and Go
    For i = 0 To (namesCount - 1)
        If InStr(pgFileNames(i), "XXXXX") <> 0 Then
            pgFileNames(i) = Replace(pgFileNames(i), "XXXXX", "44444")
        End If
    Next i
    status = swPackAndGo.SetDocumentSaveToNames(pgFileNames)
    
    ' Set folder where to save the files
    myPath = "C:\Users\DRO\Desktop\Temp PDF\"
    status = swPackAndGo.SetSaveToName(True, myPath)
    
    ' Flatten the Pack and Go folder structure; save all files to the root directory
    swPackAndGo.FlattenToSingleFolder = True

    ' Add a prefix and suffix to the new Pack and Go filenames
    swPackAndGo.AddPrefix = "SW_"
    swPackAndGo.AddSuffix = "_PackAndGo"

    ' Pack and Go
    statuses = swModelDocExt.SavePackAndGo(swPackAndGo)

End Sub

Attention à ne pas oublier la ligne :

status = swPackAndGo.SetDocumentSaveToNames(pgFileNames)

après la boucle permettant de renommer les fichiers comprenant "XXXXX" sinon le PackAndGo ne tient pas compte de la modification.

Cordialement,

sev-et-fab · Avril 25, 2019, 5:59

Bonjour, apres essai de ta macro épurée cela ne change pas le nom du fichier

je vous joins un asm pour essai pour voir ci cela fonctionne chez vous

xxxxx.zip

d.roger · Avril 25, 2019, 8:31

Bonjour,

après essai de ma macro sur ton assemblage, celle-ci fonctionne en mettant la série de X en minuscule (x).

Cordialement,

sev-et-fab · Avril 25, 2019, 8:59

J'avais fais plusieurs essai mais je n'avais pas penser à cela. Merci

Par contre cela ne modifie pas le nom des plans qui sont avec mon assemblage et mes pieces? avez-vous une idée?

d.roger · Avril 25, 2019, 5:06

Bonjour,

Non cela ne modifie pas le nom du plan car le fichier plan ne fait pas, à proprement parlé, parti de la liste des fichiers du PackAndGo mais n'est embarqué que par l'intermédiaire d'une coche de la fonction. Tu peux cependant dans ta macro prévoir de renommer tous les plans concernés, après la fonction de PackAndGo, par les fonctions VBA standard de gestion des fichiers, tu trouveras des informations permettant de le faire ICI.

Cordialement,

sev-et-fab · Avril 26, 2019, 6:21

Merci beaucoup, je pourrais me débrouiller avec cette gestion externe à Solidworks.

J'ai une dernière requête, est-ce possible d'exclure dans la macro PackAndGo les fichiers qui n'ont pas dans le nom de fichiers 'XXXXX'

d.roger · Avril 26, 2019, 9:15

Bonjour,

Essayes en mettant :

For i = 0 To (namesCount - 1)
    If InStr(pgFileNames(i), "xxxxx") <> 0 Then
        pgFileNames(i) = Replace(pgFileNames(i), "xxxxx", "44444")
    Else
        pgFileNames(i) = ""
    End If
Next i
status = swPackAndGo.SetDocumentSaveToNames(pgFileNames)

Cordialement,